BImage a;
BImage b;
boolean utahImg;
int NSK = 1000;
Sketcher[] skets;

void setup() {
  size(200,200);
  a = loadImage("colorado.jpg");
  b = loadImage("utah.jpg");

  background(255);
  skets = new Sketcher[NSK];

  for(int i=0;i<NSK;i++) {
    skets[i] = new Sketcher(random(width),random(height), a, random(2));
  }

  utahImg = true;
}

void loop() {

  for(int i=0;i<NSK;i++) {
    skets[i].update();
    skets[i].draw();
  }

}

void mousePressed() {
  utahImg=!utahImg;

  if (!utahImg) {
    for(int i=0;i<NSK;i++) {
      skets[i].changeImg(b);
    }
  }
  else {
    for(int i=0;i<NSK;i++) {
      skets[i].changeImg(a);
    }
  }
}

class Sketcher {
  float xPos;
  float yPos;
  float xPrev;
  float yPrev;
  color col;
  BImage img;
  float speed;

  Sketcher(float xp, float yp, BImage i, float sp) {
    xPos = xp;
    yPos = yp;
    xPrev = xp;
    yPrev = yp;
    img = i;
    col = color(0,0,0);
    speed = sp;
  }

  void draw() {
    stroke(col);
    line(xPos, yPos, xPrev, yPrev);

  }

  void update() {
    xPrev = xPos;
    yPrev = yPos;

    xPos += random(-speed, speed);
    yPos += random(-speed, speed);

    xPos = constrain(xPos, 0, width);
    yPos = constrain(yPos, 0, height);

    col = img.pixels[constrain((int)xPos+(int)yPos*width,0,(width*height)-1)];
  }

  void changeImg(BImage newImg) {
    img = newImg;
  }

}